Jak používat funkci Excel VLOOKUP -

souhrn

VLOOKUP je funkce aplikace Excel pro vyhledávání dat v tabulce uspořádané svisle. VLOOKUP podporuje přibližnou a přesnou shodu a zástupné znaky (*?) Pro částečné shody. Hodnoty vyhledávání se musí objevit v prvním sloupci tabulky předané do VLOOKUP.

Účel

Vyhledejte hodnotu v tabulce podle shody v prvním sloupci

Návratová hodnota

Odpovídající hodnota z tabulky.

Syntax

= VLOOKUP (hodnota, tabulka, col_index, (range_lookup))

Argumenty

value - Hodnota, která se má hledat v prvním sloupci tabulky.
tabulka - Tabulka, ze které se má načíst hodnota.
col_index - sloupec v tabulce, ze kterého se má načíst hodnota.
range_lookup - (volitelně) TRUE = přibližná shoda (výchozí). FALSE = přesná shoda.

Verze

Excel 2003

Poznámky k použití

VLOOKUP je funkce aplikace Excel pro získávání dat z tabulky uspořádané svisle. Hodnoty vyhledávání se musí objevit v prvním sloupci tabulky předané do VLOOKUP. VLOOKUP podporuje přibližnou a přesnou shodu a zástupné znaky (*?) Pro částečné shody.

V je pro vertikální

Účelem VLOOKUP je získat informace z takto uspořádané tabulky:

Pomocí čísla objednávky ve sloupci B jako vyhledávací hodnoty může VLOOKUP získat ID zákazníka, částku, jméno a stát pro jakoukoli objednávku. Například pro získání jména zákazníka pro objednávku 1004 je vzorec:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Pro horizontální data můžete použít HLOOKUP, INDEX a MATCH nebo XLOOKUP.

VLOOKUP je založen na číslech sloupců

Když používáte VLOOKUP, představte si, že každý sloupec v tabulce je očíslován, počínaje zleva. Chcete-li získat hodnotu z konkrétního sloupce, zadejte příslušné číslo jako „index sloupce“. Například index sloupce k načtení křestního jména níže je 2:

Příjmení a e-mail lze získat pomocí sloupců 3 a 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP vypadá jen dobře

VLOOKUP se může dívat pouze doprava. Data, která chcete načíst (výsledné hodnoty), se mohou objevit v libovolném sloupci napravo od vyhledávacích hodnot:

Pokud potřebujete vyhledat hodnoty nalevo, přečtěte si INDEX a MATCH nebo XLOOKUP.

Přesná a přibližná shoda

VLOOKUP má dva režimy shody, přesný a přibližný. Název argumentu, který řídí shodu, je „ range_lookup “. Toto je matoucí název, protože se zdá, že má něco společného s rozsahy buněk jako A1: A10. Ve skutečnosti slovo „range“ v tomto případě odkazuje na „range of values“ - když je range_lookup TRUE, VLOOKUP bude odpovídat spíše rozsahu hodnot než přesné hodnotě. Dobrým příkladem je použití VLOOKUP pro výpočet známek.

Je důležité si uvědomit, že range_lookup má výchozí hodnotu TRUE, což znamená, že VLOOKUP bude ve výchozím nastavení používat přibližnou shodu, což může být nebezpečné. Nastavit range_lookup na FALSE k vynucení přesné shody:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Poznámka: Pro přesnou shodu můžete místo FALSE zadat také nulu (0).

Přesná shoda

Ve většině případů budete pravděpodobně chtít použít VLOOKUP v režimu přesné shody. To dává smysl, když máte jedinečný klíč, který můžete použít jako vyhledávací hodnotu, například název filmu v těchto datech:

Vzorec v H6 k vyhledání roku , založený na přesné shodě názvu filmu, je:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Přibližná shoda

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.